felix.ruizdearcaute/app-organization-portal
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

added migrations to flush again

Browse Source
This commit is contained in:
felix
2025-02-13 17:04:23 +01:00
parent 9ea9d90751
commit 741a7cae2c
10 changed files with 258 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

36
config/migrations/2025/20250213162849-update-worship-consumer-again/20250213162924-flush-eredienst-mandatarissen-consumer-containers.sparql Normal file
View File

@@ -0,0 +1,36 @@
PREFIX mu: <http://mu.semte.ch/vocabularies/core/>
PREFIX task: <http://redpencil.data.gift/vocabularies/tasks/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX nie: <http://www.semanticdesktop.org/ontologies/2007/01/19/nie#>
PREFIX ext: <http://mu.semte.ch/vocabularies/ext/>
PREFIX oslc: <http://open-services.net/ns/core#>
PREFIX cogs: <http://vocab.deri.ie/cogs#>
PREFIX adms: <http://www.w3.org/ns/adms#>
PREFIX nfo: <http://www.semanticdesktop.org/ontologies/2007/03/22/nfo#>
PREFIX dbpedia: <http://dbpedia.org/resource/>
DELETE {
GRAPH ?g {
?container ?containerP ?containerO.
}
} WHERE {
# Please note, if you ever copy/paste this migration the next time, there should be 4
# operation URI's in total. Since two consumers
VALUES ?operation {
<http://redpencil.data.gift/id/jobs/concept/JobOperation/deltas/consumer/wsSensitive>
<http://redpencil.data.gift/id/jobs/concept/JobOperation/deltas/consumer/wsSensitiveDeltaFileSyncing>
}
GRAPH ?g {
?job a <http://vocab.deri.ie/cogs#Job>;
task:operation ?operation.
?task dct:isPartOf ?job;
task:resultsContainer ?container.
?container a nfo:DataContainer;
?containerP ?containerO.
}
}

33
config/migrations/2025/20250213162849-update-worship-consumer-again/20250213162925-flush-eredienst-mandatarissen-consumer-tasks.sparql Normal file
View File

@@ -0,0 +1,33 @@
PREFIX mu: <http://mu.semte.ch/vocabularies/core/>
PREFIX task: <http://redpencil.data.gift/vocabularies/tasks/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX nie: <http://www.semanticdesktop.org/ontologies/2007/01/19/nie#>
PREFIX ext: <http://mu.semte.ch/vocabularies/ext/>
PREFIX oslc: <http://open-services.net/ns/core#>
PREFIX cogs: <http://vocab.deri.ie/cogs#>
PREFIX adms: <http://www.w3.org/ns/adms#>
PREFIX nfo: <http://www.semanticdesktop.org/ontologies/2007/03/22/nfo#>
PREFIX dbpedia: <http://dbpedia.org/resource/>
DELETE {
GRAPH ?g {
?task ?taskP ?taskO.
}
} WHERE {
# Please note, if you ever copy/paste this migration the next time, there should be 4
# operation URI's in total. Since two consumers
VALUES ?operation {
<http://redpencil.data.gift/id/jobs/concept/JobOperation/deltas/consumer/wsSensitive>
<http://redpencil.data.gift/id/jobs/concept/JobOperation/deltas/consumer/wsSensitiveDeltaFileSyncing>
}
GRAPH ?g {
?job a <http://vocab.deri.ie/cogs#Job>;
task:operation ?operation.
?task dct:isPartOf ?job;
?taskP ?taskO.
}
}

31
config/migrations/2025/20250213162849-update-worship-consumer-again/20250213162926-flush-eredienst-mandatarissen-consumer-jobs.sparql Normal file
View File

@@ -0,0 +1,31 @@
PREFIX mu: <http://mu.semte.ch/vocabularies/core/>
PREFIX task: <http://redpencil.data.gift/vocabularies/tasks/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX nie: <http://www.semanticdesktop.org/ontologies/2007/01/19/nie#>
PREFIX ext: <http://mu.semte.ch/vocabularies/ext/>
PREFIX oslc: <http://open-services.net/ns/core#>
PREFIX cogs: <http://vocab.deri.ie/cogs#>
PREFIX adms: <http://www.w3.org/ns/adms#>
PREFIX nfo: <http://www.semanticdesktop.org/ontologies/2007/03/22/nfo#>
PREFIX dbpedia: <http://dbpedia.org/resource/>
DELETE {
GRAPH ?g {
?job ?jobP ?jobO.
}
} WHERE {
# Please note, if you ever copy/paste this migration the next time, there should be 4
# operation URI's in total. Since two consumers
VALUES ?operation {
<http://redpencil.data.gift/id/jobs/concept/JobOperation/deltas/consumer/wsSensitive>
<http://redpencil.data.gift/id/jobs/concept/JobOperation/deltas/consumer/wsSensitiveDeltaFileSyncing>
}
GRAPH ?g {
?job a <http://vocab.deri.ie/cogs#Job>;
task:operation ?operation;
?jobP ?jobO.
}
}

17
config/migrations/2025/20250213162849-update-worship-consumer-again/20250213162927-remove-loket-persons-birthdates.sparql Normal file
View File

@@ -0,0 +1,17 @@
DELETE {
GRAPH ?g {
?s ?p ?o
}
}
WHERE {
VALUES ?g {
<http://mu.semte.ch/graphs/worship-privacy-centric-graph>
<http://mu.semte.ch/graphs/worship-service>
}
GRAPH ?g {
?s ?p ?o.
FILTER NOT EXISTS {
?s a ?type.
}
}
}

33
config/migrations/2025/20250213162849-update-worship-consumer-again/20250213162928-remove-loket-persons-birthdates.sparql Normal file
View File

@@ -0,0 +1,33 @@
PREFIX ch: <http://data.lblod.info/vocabularies/contacthub/>
PREFIX mandaat: <http://data.vlaanderen.be/ns/mandaat#>
PREFIX org: <http://www.w3.org/ns/org#>
PREFIX person: <http://www.w3.org/ns/person#>
PREFIX persoon: <https://data.vlaanderen.be/ns/persoon#>
# Delete birthdates
DELETE {
GRAPH <http://mu.semte.ch/graphs/worship-privacy-centric-graph> {
?birthDate ?p ?o .
}
} WHERE {
VALUES ?g {
<http://mu.semte.ch/graphs/shared>
<http://mu.semte.ch/graphs/worship-service>
}
GRAPH ?g {
?person a person:Person .
}
FILTER EXISTS {
GRAPH <http://mu.semte.ch/graphs/worship-service> {
?agent a ch:AgentInPositie ;
mandaat:isBestuurlijkeAliasVan|org:heldBy ?person .
}
}
GRAPH <http://mu.semte.ch/graphs/worship-privacy-centric-graph> {
?person persoon:heeftGeboorte ?birthDate .
?birthDate ?p ?o .
}
}

39
config/migrations/2025/20250213162849-update-worship-consumer-again/20250213162929-remove-loket-persons-identifiers.sparql Normal file
View File

@@ -0,0 +1,39 @@
PREFIX ch: <http://data.lblod.info/vocabularies/contacthub/>
PREFIX generiek: <https://data.vlaanderen.be/ns/generiek#>
PREFIX mandaat: <http://data.vlaanderen.be/ns/mandaat#>
PREFIX org: <http://www.w3.org/ns/org#>
PREFIX person: <http://www.w3.org/ns/person#>
PREFIX persoon: <https://data.vlaanderen.be/ns/persoon#>
# Delete identifiers
DELETE {
GRAPH <http://mu.semte.ch/graphs/worship-privacy-centric-graph> {
?identifier ?pidentifier ?oidentifier .
?structuredIdentifier ?pstructuredIdentifier ?ostructuredIdentifier .
}
} WHERE {
VALUES ?g {
<http://mu.semte.ch/graphs/shared>
<http://mu.semte.ch/graphs/worship-service>
}
GRAPH ?g {
?person a person:Person .
}
FILTER EXISTS {
GRAPH <http://mu.semte.ch/graphs/worship-service> {
?agent a ch:AgentInPositie ;
mandaat:isBestuurlijkeAliasVan|org:heldBy ?person .
}
}
GRAPH <http://mu.semte.ch/graphs/worship-privacy-centric-graph> {
?person persoon:registratie ?identifier .
?identifier generiek:gestructureerdeIdentificator ?structuredIdentifier ;
?pidentifier ?oidentifier .
?structuredIdentifier ?pstructuredIdentifier ?ostructuredIdentifier .
}
}

36
config/migrations/2025/20250213162849-update-worship-consumer-again/20250213162930-remove-loket-persons.sparql Normal file
View File

@@ -0,0 +1,36 @@
PREFIX ch: <http://data.lblod.info/vocabularies/contacthub/>
PREFIX mandaat: <http://data.vlaanderen.be/ns/mandaat#>
PREFIX org: <http://www.w3.org/ns/org#>
PREFIX person: <http://www.w3.org/ns/person#>
# Delete persons
DELETE {
GRAPH ?g {
?person ?p ?o .
}
GRAPH <http://mu.semte.ch/graphs/worship-privacy-centric-graph> {
?person ?pprivate ?oprivate .
}
} WHERE {
VALUES ?g {
<http://mu.semte.ch/graphs/shared>
<http://mu.semte.ch/graphs/worship-service>
}
GRAPH ?g {
?person a person:Person ;
?p ?o .
}
FILTER EXISTS {
GRAPH <http://mu.semte.ch/graphs/worship-service> {
?agent a ch:AgentInPositie ;
mandaat:isBestuurlijkeAliasVan|org:heldBy ?person .
}
}
GRAPH <http://mu.semte.ch/graphs/worship-privacy-centric-graph> {
?person ?pprivate ?oprivate .
}
}

22
config/migrations/2025/20250213162849-update-worship-consumer-again/20250213162931-contact-points.sparql Normal file
View File

@@ -0,0 +1,22 @@
DELETE {
GRAPH <http://mu.semte.ch/graphs/worship-service> {
?contactPoint ?pcontactPoint ?ocontactPoint .
?address ?paddress ?oaddress .
}
} WHERE {
GRAPH <http://mu.semte.ch/graphs/worship-service> {
?agent a <http://data.lblod.info/vocabularies/contacthub/AgentInPositie> .
OPTIONAL {
?agent <http://schema.org/contactPoint> ?contactPoint .
?contactPoint ?pcontactPoint ?ocontactPoint .
OPTIONAL {
?contactPoint <http://www.w3.org/ns/locn#address> ?address .
?address ?paddress ?oaddress .
}
}
}
}

10
config/migrations/2025/20250213162849-update-worship-consumer-again/20250213162932-remove-agents-in-position.sparql Normal file
View File

@@ -0,0 +1,10 @@
DELETE {
GRAPH <http://mu.semte.ch/graphs/worship-service> {
?agent ?pagent ?oagent .
}
} WHERE {
GRAPH <http://mu.semte.ch/graphs/worship-service> {
?agent a <http://data.lblod.info/vocabularies/contacthub/AgentInPositie> ;
?pagent ?oagent .
}
}

1
config/migrations/2025/20250213162849-update-worship-consumer-again/20250213162933-flush-landing-zone.sparql Normal file
View File

@@ -0,0 +1 @@
CLEAR GRAPH <http://mu.semte.ch/graphs/landing-zone/worship-services-sensitive>