OP-3810: added migration to handle in oprichting erediensten + changelog edit

CHANGELOG.md

@@ -6,10 +6,11 @@
 - Frontend [v1.38.0]
 - Added Juridische vorm [OP-3816] [OP-3820]
 - Frontend [v1.39.0]
+- "In Oprichting" bestuursorgaan lifecycle [OP-3810]
 
 ### Deploy notes
 ```
-drc up -d link-adressenregister-uri frontend
+drc up -d link-adressenregister-uri frontend construct-organization-relationships dispatcher
 drc restart resource migrations
 ```
 

config/migrations/2026/20260630100000-cleanup-in-oprichting-worship-services.sparql

@@ -0,0 +1,85 @@
+PREFIX mandaat: <http://data.vlaanderen.be/ns/mandaat#>
+PREFIX ere: <http://data.lblod.info/vocabularies/erediensten/>
+PREFIX besluit: <http://data.vlaanderen.be/ns/besluit#>
+PREFIX generiek: <https://data.vlaanderen.be/ns/generiek#>
+PREFIX regorg: <http://www.w3.org/ns/regorg#>
+PREFIX org: <http://www.w3.org/ns/org#>
+
+DELETE {
+  GRAPH <http://mu.semte.ch/graphs/worship-service> {
+    ?otherOrgaanInTime ?p ?o .
+    ?s ?p2 ?otherOrgaanInTime .
+  }
+}
+WHERE {
+  GRAPH <http://mu.semte.ch/graphs/worship-service> {
+    ?worshipService a ere:BestuurVanDeEredienst ;
+      regorg:orgStatus <http://lblod.data.gift/concepts/abf4fee82019f88cf122f986830621ab> .
+
+    ?bestuursorgaan besluit:bestuurt ?worshipService .
+
+    ?otherOrgaanInTime generiek:isTijdspecialisatieVan ?bestuursorgaan .
+
+    {
+      SELECT ?bestuursorgaan (SAMPLE(?orgaanInTime) AS ?keptOrgaanInTime) {
+        GRAPH <http://mu.semte.ch/graphs/worship-service> {
+          ?orgaanInTime generiek:isTijdspecialisatieVan ?bestuursorgaan .
+        }
+      }
+      GROUP BY ?bestuursorgaan
+    }
+
+    FILTER(?otherOrgaanInTime != ?keptOrgaanInTime)
+
+    { ?otherOrgaanInTime ?p ?o . }
+    UNION
+    { ?s ?p2 ?otherOrgaanInTime . }
+  }
+};
+
+DELETE {
+  GRAPH <http://mu.semte.ch/graphs/worship-service> {
+    ?mandate ?p ?o .
+    ?s ?p2 ?mandate .
+  }
+}
+WHERE {
+  GRAPH <http://mu.semte.ch/graphs/worship-service> {
+    ?worshipService a ere:BestuurVanDeEredienst ;
+      regorg:orgStatus <http://lblod.data.gift/concepts/abf4fee82019f88cf122f986830621ab> .
+
+    ?bestuursorgaan besluit:bestuurt ?worshipService .
+    ?orgaanInTime generiek:isTijdspecialisatieVan ?bestuursorgaan .
+
+    ?orgaanInTime org:hasPost ?mandate .
+    ?mandate a mandaat:Mandaat ;
+      org:role ?role .
+
+    FILTER(?role NOT IN (
+      <http://data.vlaanderen.be/id/concept/BestuursfunctieCode/67e6e585166cd97575b3e17ffc430a43>,
+      <http://data.vlaanderen.be/id/concept/BestuursfunctieCode/5ac134b9800b81da3c450d6b9605cef2>,
+      <http://data.vlaanderen.be/id/concept/BestuursfunctieCode/180d13930d6f1a3938e0aa7fa9990002>
+    ))
+
+    { ?mandate ?p ?o . }
+    UNION
+    { ?s ?p2 ?mandate . }
+  }
+};
+
+DELETE {
+  GRAPH <http://mu.semte.ch/graphs/worship-service> {
+    ?orgaanInTime mandaat:bindingEinde ?endDate .
+  }
+}
+WHERE {
+  GRAPH <http://mu.semte.ch/graphs/worship-service> {
+    ?worshipService a ere:BestuurVanDeEredienst ;
+      regorg:orgStatus <http://lblod.data.gift/concepts/abf4fee82019f88cf122f986830621ab> .
+
+    ?bestuursorgaan besluit:bestuurt ?worshipService .
+    ?orgaanInTime generiek:isTijdspecialisatieVan ?bestuursorgaan .
+
+    ?orgaanInTime mandaat:bindingEinde ?endDate .
+  }
+};