chore: regenerate full addresses to reflect address changes

This migration regenerates the `locn:fullAddress` triples for addresses in a
municipality involved in a merger. In essences this migration updates the
`locn:fullAddress` triple for each address changed by the migrations in the
previous commit.

Notes
- The migration is split over two queries, one for addresses without a box
  number and one for addresses with a box number. This avoids complicating the
  query with conditional logic at the cost of code duplication in the queries.
- In the existing full address triples two different notations are used to
  separate the box and building number. OP currently separates them simply by a
  space, which is what this migration matches for. But some historical data uses
  a dash "-" to separate building and box number. Consequently, this migration
  might match more address resources than strictly updated for the municipality
  merges.

config/migrations-triggering-indexing/2024/20241217082404-mergers-2025--update-addresses/20241217082404-change-zwijndrecht-to-province-east-flanders.sparql

@@ -0,0 +1,27 @@
+PREFIX locn: <http://www.w3.org/ns/locn#>
+PREFIX adres: <https://data.vlaanderen.be/ns/adres#>
+PREFIX organisatie: <https://data.vlaanderen.be/ns/organisatie#>
+PREFIX org: <http://www.w3.org/ns/org#>
+
+DELETE {
+  GRAPH ?g {
+    ?address locn:adminUnitL2 "Antwerpen".
+  }
+} INSERT {
+  GRAPH ?g {
+    ?address locn:adminUnitL2 "Oost-Vlaanderen".
+  }
+} WHERE {
+  GRAPH ?g {
+    ?address a locn:Address;
+             adres:gemeentenaam "Zwijndrecht";
+             locn:adminUnitL2 "Antwerpen"
+    FILTER (EXISTS { ?site organisatie:bestaatUit ?address. } ||
+            EXISTS { ?site org:siteAddress/locn:address ?address. })
+
+  }
+  VALUES ?g {
+    <http://mu.semte.ch/graphs/worship-service>
+    <http://mu.semte.ch/graphs/administrative-unit>
+  }
+}

config/migrations-triggering-indexing/2024/20241217082404-mergers-2025--update-addresses/20241217082944-update-address-municipality-to-merged-municipality-name.sparql

@@ -0,0 +1,51 @@
+PREFIX adres: <https://data.vlaanderen.be/ns/adres#>
+PREFIX locn: <http://www.w3.org/ns/locn#>
+PREFIX organisatie: <https://data.vlaanderen.be/ns/organisatie#>
+PREFIX org: <http://www.w3.org/ns/org#>
+
+DELETE {
+  GRAPH ?g {
+    ?address adres:gemeentenaam ?oldMunicipality.
+  }
+}
+INSERT {
+  GRAPH ?g {
+    ?address adres:gemeentenaam ?newMunicipality.
+  }
+}
+WHERE {
+  GRAPH ?g {
+    ?address a locn:Address;
+             adres:gemeentenaam ?oldMunicipality.
+    FILTER (EXISTS { ?site organisatie:bestaatUit ?address. } ||
+            EXISTS { ?site org:siteAddress/locn:address ?address. })
+  }
+  VALUES ?g {
+    <http://mu.semte.ch/graphs/administrative-unit>
+    <http://mu.semte.ch/graphs/worship-service>
+  }
+  VALUES (?oldMunicipality ?newMunicipality) {
+    ("Borsbeek" "Antwerpen")
+    ("Galmaarden" "Pajottegem")
+    ("Gooik" "Pajottegem")
+    ("Herne" "Pajottegem")
+    ("Ruiselede" "Wingene")
+    ("Meulebeke" "Tielt")
+    ("De Pinte" "Nazareth-De Pinte")
+    ("Nazareth" "Nazareth-De Pinte")
+    ("Wachtebeke" "Lochristi")
+    ("Moerbeke" "Lokeren")
+    ("Melle" "Merelbeke-Melle")
+    ("Merelbeke" "Merelbeke-Melle")
+    ("Beveren" "Beveren-Kruibeke-Zwijndrecht")
+    ("Kruibeke" "Beveren-Kruibeke-Zwijndrecht")
+    ("Zwijndrecht" "Beveren-Kruibeke-Zwijndrecht")
+    ("Bilzen" "Bilzen-Hoeselt")
+    ("Hoeselt" "Bilzen-Hoeselt")
+    ("Borgloon" "Tongeren-Borgloon")
+    ("Tongeren" "Tongeren-Borgloon")
+    ("Ham" "Tessenderlo-Ham")
+    ("Tessenderlo" "Tessenderlo-Ham")
+    ("Kortessem" "Hasselt")
+  }
+}

config/migrations-triggering-indexing/2024/20241217082404-mergers-2025--update-addresses/20241217083314-regenerate-full-address-triple-for-changed-addresses.sparql

@@ -0,0 +1,92 @@
+PREFIX locn: <http://www.w3.org/ns/locn#>
+PREFIX adres: <https://data.vlaanderen.be/ns/adres#>
+PREFIX organisatie: <https://data.vlaanderen.be/ns/organisatie#>
+PREFIX org: <http://www.w3.org/ns/org#>
+
+DELETE {
+  GRAPH ?g {
+    ?address locn:fullAddress ?fullAddress.
+  }
+} INSERT {
+  GRAPH ?g {
+    ?address locn:fullAddress ?newFullAddress.
+  }
+} WHERE {
+  GRAPH ?g {
+    ?address locn:fullAddress ?fullAddress;
+             locn:thoroughfare ?street;
+             adres:Adresvoorstelling.huisnummer ?buildingNo;
+             locn:postCode ?postalCode;
+             adres:gemeentenaam ?municipality;
+             adres:land ?country.
+    FILTER NOT EXISTS { ?address adres:Adresvoorstelling.busnummer ?boxNo. }
+    FILTER (EXISTS { ?site organisatie:bestaatUit ?address. } ||
+            EXISTS { ?site org:siteAddress/locn:address ?address. })
+    FILTER (?municipality IN (
+                              "Antwerpen",
+                              "Pajottegem",
+                              "Wingene",
+                              "Tielt",
+                              "Nazareth-De Pinte",
+                              "Lochristi",
+                              "Lokeren",
+                              "Merelbeke-Melle",
+                              "Beveren-Kruibeke-Zwijndrecht",
+                              "Bilzen-Hoeselt",
+                              "Tongeren-Borgloon",
+                              "Tessenderlo-Ham",
+                              "Hasselt"
+                              ))
+    BIND (CONCAT(?street, " ", ?buildingNo, ", ", ?postalCode, " ", ?municipality, ", ", ?country) AS ?newFullAddress)
+    FILTER (?fullAddress != ?newFullAddress)
+  }
+
+  VALUES ?g {
+    <http://mu.semte.ch/graphs/administrative-unit>
+    <http://mu.semte.ch/graphs/worship-service>
+  }
+}
+;
+DELETE {
+  GRAPH ?g {
+    ?address locn:fullAddress ?fullAddress.
+  }
+} INSERT {
+  GRAPH ?g {
+    ?address locn:fullAddress ?newFullAddress.
+  }
+} WHERE {
+  GRAPH ?g {
+    ?address locn:fullAddress ?fullAddress;
+             locn:thoroughfare ?street;
+             adres:Adresvoorstelling.huisnummer ?buildingNo;
+             adres:Adresvoorstelling.busnummer ?boxNo;
+             locn:postCode ?postalCode;
+             adres:gemeentenaam ?municipality;
+             adres:land ?country.
+    FILTER (EXISTS { ?site organisatie:bestaatUit ?address. } ||
+            EXISTS { ?site org:siteAddress/locn:address ?address. })
+    FILTER (?municipality IN (
+                              "Antwerpen",
+                              "Pajottegem",
+                              "Wingene",
+                              "Tielt",
+                              "Nazareth-De Pinte",
+                              "Lochristi",
+                              "Lokeren",
+                              "Merelbeke-Melle",
+                              "Beveren-Kruibeke-Zwijndrecht",
+                              "Bilzen-Hoeselt",
+                              "Tongeren-Borgloon",
+                              "Tessenderlo-Ham",
+                              "Hasselt"
+                              ))
+    BIND (CONCAT(?street, " ", ?buildingNo, " ", ?boxNo, ", ", ?postalCode, " ", ?municipality, ", ", ?country) AS ?newFullAddress)
+    FILTER (?fullAddress != ?newFullAddress)
+  }
+
+  VALUES ?g {
+    <http://mu.semte.ch/graphs/administrative-unit>
+    <http://mu.semte.ch/graphs/worship-service>
+  }
+}

config/migrations/2024/20241218115931-add-missing-werkingsgebieden-ocmw.sparql

@@ -0,0 +1,24 @@
+INSERT {
+  GRAPH <http://mu.semte.ch/graphs/administrative-unit> {
+    ?s <http://data.vlaanderen.be/ns/besluit#werkingsgebied> ?gebied.
+  }
+}
+WHERE {
+  ?s a <http://data.vlaanderen.be/ns/besluit#Bestuurseenheid> ;
+      <http://www.w3.org/ns/org#classification>
+        <http://data.vlaanderen.be/id/concept/BestuurseenheidClassificatieCode/5ab0e9b8a3b2ca7c5e000002>; # ocmw
+      skos:prefLabel ?label.
+
+  FILTER NOT EXISTS {
+    ?s <http://data.vlaanderen.be/ns/besluit#werkingsgebied> ?ocmwGebied.
+  }
+
+  ?gemeente <http://www.w3.org/ns/org#linkedTo> ?s.
+
+  ?gemeente <http://www.w3.org/ns/org#classification>
+    <http://data.vlaanderen.be/id/concept/BestuurseenheidClassificatieCode/5ab0e9b8a3b2ca7c5e000001>.
+
+  GRAPH <http://mu.semte.ch/graphs/administrative-unit> {
+    ?gemeente <http://data.vlaanderen.be/ns/besluit#werkingsgebied> ?gebied.
+  }
+}

docker-compose.yml

@@ -179,7 +179,7 @@ services:
     restart: always
     logging: *default-logging
   frontend:
-    image: lblod/frontend-organization-portal:1.27.1
+    image: lblod/frontend-organization-portal:1.28.0
     volumes:
       - ./config/frontend/add-x-frame-options-header.conf:/config/add-x-frame-options.conf
     environment: