Add migration to remove duplicated organizations

Add migration to update change event and status
Add migration to fix change event date
2022-03-08 17:58:04 +01:00 · 2022-03-08 17:57:56 +01:00 · 2022-03-08 17:57:50 +01:00 · 2022-03-08 17:57:42 +01:00 · 2022-02-10 16:02:13 +01:00 · 2022-02-10 14:23:10 +01:00
12 changed files with 275 additions and 3 deletions
--- a/config/migrations/2022/20220125185900-rename-change-event-result-relationship-predicate.sparql
+++ b/config/migrations/2022/20220125185900-rename-change-event-result-relationship-predicate.sparql
@@ -0,0 +1,18 @@
+PREFIX ext: <http://mu.semte.ch/vocabularies/ext/>
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX org: <http://www.w3.org/ns/org#>
+
+DELETE {
+    GRAPH ?g {
+      ?changeEventResult org:organization ?organization .
+    }
+} INSERT {
+    GRAPH ?g {
+      ?changeEventResult ext:resultingOrganization ?organization .
+    }
+} WHERE {
+  GRAPH ?g {
+    ?changeEventResult a <http://lblod.data.gift/vocabularies/organisatie/VeranderingsgebeurtenisResultaat> ;
+            org:organization ?organization .
+  }
+}
--- a/config/migrations/2022/20220202120000-primary-contacts.sparql
+++ b/config/migrations/2022/20220202120000-primary-contacts.sparql
@@ -0,0 +1,22 @@
+# cf 20220110100000-secondary-contacts.sparql for context.
+# In case it's not a secondary contactpoint (a contactpoint without an address if multiple contact points exist for one entity/mandataris)
+PREFIX locn: <http://www.w3.org/ns/locn#>
+PREFIX schema: <http://schema.org/>
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+INSERT {
+  GRAPH <http://mu.semte.ch/graphs/organisatieportaal> {
+    ?contactPoint
+      schema:contactType "Primary"
+  }
+}
+WHERE {
+  GRAPH <http://mu.semte.ch/graphs/organisatieportaal> {
+    ?contactPoint 
+      a schema:ContactPoint.
+    FILTER NOT EXISTS {
+      ?contactPoint
+        schema:contactType "Secondary"
+    }
+  }
+}
--- a/config/migrations/2022/20220203100000-secondary-contacts.sparql
+++ b/config/migrations/2022/20220203100000-secondary-contacts.sparql
@@ -0,0 +1,24 @@
+PREFIX locn: <http://www.w3.org/ns/locn#>
+PREFIX schema: <http://schema.org/>
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+INSERT {
+  GRAPH <http://mu.semte.ch/graphs/organisatieportaal> {
+    ?secondary
+      schema:contactType "Secondary"
+  }
+}
+WHERE  {
+  GRAPH <http://mu.semte.ch/graphs/organisatieportaal> {
+    ?primary 
+      a schema:ContactPoint;
+      locn:address ?a1;
+      schema:telephone ?t1.
+    ?mandataris schema:contactPoint ?primary, ?secondary.
+    ?secondary
+      schema:telephone ?t2.
+    FILTER NOT EXISTS {
+     ?secondary locn:address ?a2.
+    }
+  }
+}    
--- a/config/migrations/2022/20220304152947-delete-centraal-kerkbestuur-wachtebeke.sparql
+++ b/config/migrations/2022/20220304152947-delete-centraal-kerkbestuur-wachtebeke.sparql
@@ -0,0 +1,38 @@
+DELETE {
+  GRAPH ?g {
+    ?representatieveOrgaan <http://www.w3.org/ns/org#linkedTo> ?bestuur .
+    ?bestuur ?pbestuur ?obestuur .
+    ?primarySite ?pprimarySite ?oprimarySite .
+    ?address ?paddress ?oaddress .
+    ?contactPoint ?pcontactPoint ?ocontactPoint .
+    ?identifier ?pidentifier ?oidentifier .
+    ?structuredIdentifier ?pstructuredIdentifier ?ostructuredIdentifier .
+  }
+} WHERE {
+  GRAPH ?g {
+    VALUES ?bestuur {
+      <http://data.lblod.info/id/centraleBesturenVanDeEredienst/6167E3E2375CFC000A0007C2>
+      <http://data.lblod.info/id/centraleBesturenVanDeEredienst/616FE419375CFC000A000893>
+    }
+
+    ?representatieveOrgaan <http://www.w3.org/ns/org#linkedTo> ?bestuur .
+
+    ?bestuur <http://www.w3.org/ns/org#hasPrimarySite> ?primarySite ;
+      <http://www.w3.org/ns/adms#identifier> ?identifier ;
+      ?pbestuur ?obestuur .
+
+    ?primarySite <https://data.vlaanderen.be/ns/organisatie#bestaatUit> ?address ;
+      <http://www.w3.org/ns/org#siteAddress> ?contactPoint ;
+      ?pprimarySite ?oprimarySite .
+
+    ?address ?paddress ?oaddress .
+
+    ?contactPoint ?pcontactPoint ?ocontactPoint .
+
+    ?identifier <https://data.vlaanderen.be/ns/generiek#gestructureerdeIdentificator> ?structuredIdentifier ;
+      ?pidentifier ?oidentifier .
+
+    ?structuredIdentifier ?pstructuredIdentifier ?ostructuredIdentifier .
+  }
+}
+
--- a/config/migrations/2022/20220307092611-update-date-change-event-Zonhoven.sparql
+++ b/config/migrations/2022/20220307092611-update-date-change-event-Zonhoven.sparql
@@ -0,0 +1,15 @@
+PREFIX dct: <http://purl.org/dc/terms/>
+
+DELETE {
+  GRAPH ?g {
+    <http://data.lblod.info/id/veranderingsgebeurtenissen/61F90CAF51BFC225E4ECF2CA> dct:date "2021-11-28"^^xsd:date .
+  }
+} INSERT {
+  GRAPH ?g {
+    <http://data.lblod.info/id/veranderingsgebeurtenissen/61F90CAF51BFC225E4ECF2CA> dct:date "2021-12-20"^^xsd:date .
+  }
+} WHERE {
+  GRAPH ?g {
+    <http://data.lblod.info/id/veranderingsgebeurtenissen/61F90CAF51BFC225E4ECF2CA> dct:date "2021-11-28"^^xsd:date .
+  }
+}
--- a/config/migrations/2022/20220307104523-update-change-event-glabbeek.sparql
+++ b/config/migrations/2022/20220307104523-update-change-event-glabbeek.sparql
@@ -0,0 +1,26 @@
+PREFIX dct: <http://purl.org/dc/terms/>
+PREFIX regorg: <http://www.w3.org/ns/regorg#>
+
+DELETE {
+  GRAPH ?g {
+    <http://data.lblod.info/id/veranderingsgebeurtenissen/61F92B0A51BFC225E4ECF2FF>
+      dct:date "2021-02-04"^^xsd:date .
+    <http://data.lblod.info/id/besturenVanDeEredienst/2a75e67f9a8aacf52896944c59b09eb0>
+      regorg:orgStatus <http://lblod.data.gift/concepts/63cc561de9188d64ba5840a42ae8f0d6> . # Actief
+  }
+} INSERT {
+  GRAPH ?g {
+    <http://data.lblod.info/id/veranderingsgebeurtenissen/61F92B0A51BFC225E4ECF2FF>
+      dct:date "2022-02-04"^^xsd:date .
+    <http://data.lblod.info/id/besturenVanDeEredienst/2a75e67f9a8aacf52896944c59b09eb0>
+      regorg:orgStatus <http://lblod.data.gift/concepts/d02c4e12bf88d2fdf5123b07f29c9311> . # Niet Actief
+
+  }
+} WHERE {
+  GRAPH ?g {
+    <http://data.lblod.info/id/veranderingsgebeurtenissen/61F92B0A51BFC225E4ECF2FF>
+      dct:date "2021-02-04"^^xsd:date .
+    <http://data.lblod.info/id/besturenVanDeEredienst/2a75e67f9a8aacf52896944c59b09eb0>
+      regorg:orgStatus <http://lblod.data.gift/concepts/63cc561de9188d64ba5840a42ae8f0d6> .
+  }
+}
--- a/config/migrations/2022/20220307140756-remove-duplicated-bestuurseenheden.sparql
+++ b/config/migrations/2022/20220307140756-remove-duplicated-bestuurseenheden.sparql
@@ -0,0 +1,77 @@
+# Splitting the query in two because of execution time
+
+## Links to the bestuur
+
+
+
+DELETE {
+  GRAPH ?g {
+    ?representatieveOrgaan <http://www.w3.org/ns/org#linkedTo> ?bestuur .
+    ?orgaanInTijd ?porgaanInTijd ?oorgaanInTijd .
+    ?orgaan ?porgaan ?oorgaan .
+    ?betrokken ?pbetrokken ?obetrokken .
+    ?eenheid <http://data.lblod.info/vocabularies/erediensten/betrokkenBestuur> ?betrokken .
+  }
+} WHERE {
+  GRAPH ?g {
+    VALUES ?bestuur {
+      <http://data.lblod.info/id/besturenVanDeEredienst/6183A207375CFC000A000933>
+      <http://data.lblod.info/id/besturenVanDeEredienst/61AE0A9B3C1A230C43B44FFF>
+    }
+
+    ?representatieveOrgaan <http://www.w3.org/ns/org#linkedTo> ?bestuur .
+
+    OPTIONAL {
+      ?orgaanInTijd <http://data.vlaanderen.be/ns/besluit#bestuurt> ?bestuur ;
+        ?porgaanInTijd ?oorgaanInTijd .
+      
+      ?orgaan <https://data.vlaanderen.be/ns/generiek#isTijdspecialisatieVan> ?orgaanInTijd ;
+        ?porgaan ?oorgaan .
+    }
+
+    OPTIONAL {
+      ?betrokken <http://www.w3.org/ns/org#organization> ?bestuur ;
+        ?pbetrokken ?obetrokken .
+      ?eenheid <http://data.lblod.info/vocabularies/erediensten/betrokkenBestuur> ?betrokken .
+    }
+  }
+}
+
+;
+
+## Links from the bestuur
+
+DELETE {
+  GRAPH ?g {
+    ?bestuur ?pbestuur ?obestuur .
+    ?primarySite ?pprimarySite ?oprimarySite .
+    ?address ?paddress ?oaddress .
+    ?contactPoint ?pcontactPoint ?ocontactPoint .
+    ?identifier ?pidentifier ?oidentifier .
+    ?structuredIdentifier ?pstructuredIdentifier ?ostructuredIdentifier .
+  }
+} WHERE {
+  GRAPH ?g {
+    VALUES ?bestuur {
+      <http://data.lblod.info/id/besturenVanDeEredienst/6183A207375CFC000A000933>
+      <http://data.lblod.info/id/besturenVanDeEredienst/61AE0A9B3C1A230C43B44FFF>
+    }
+
+    ?bestuur <http://www.w3.org/ns/org#hasPrimarySite> ?primarySite ;
+      <http://www.w3.org/ns/adms#identifier> ?identifier ;
+      ?pbestuur ?obestuur .
+
+    ?primarySite <https://data.vlaanderen.be/ns/organisatie#bestaatUit> ?address ;
+      <http://www.w3.org/ns/org#siteAddress> ?contactPoint ;
+      ?pprimarySite ?oprimarySite .
+
+    ?address ?paddress ?oaddress .
+
+    ?contactPoint ?pcontactPoint ?ocontactPoint .
+
+    ?identifier <https://data.vlaanderen.be/ns/generiek#gestructureerdeIdentificator> ?structuredIdentifier ;
+      ?pidentifier ?oidentifier .
+
+    ?structuredIdentifier ?pstructuredIdentifier ?ostructuredIdentifier .
+  }
+}
--- a/config/migrations/20220120100418-remove-old-reasons.sparql
+++ b/config/migrations/20220120100418-remove-old-reasons.sparql
@@ -0,0 +1,11 @@
+DELETE {
+  GRAPH  <http://mu.semte.ch/graphs/organisatieportaal> {
+    ?s ?p ?o
+  }
+}
+ WHERE {
+  GRAPH  <http://mu.semte.ch/graphs/organisatieportaal> {
+    ?s a <http://mu.semte.ch/vocabularies/ext/ReasonCode>;
+        ?p ?o.
+  }
+}
--- a/config/migrations/20220120101318-insert-new-reasons.sparql
+++ b/config/migrations/20220120101318-insert-new-reasons.sparql
@@ -0,0 +1,37 @@
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX ext: <http://mu.semte.ch/vocabularies/ext/>
+PREFIX mu: <http://mu.semte.ch/vocabularies/core/>
+
+ INSERT DATA {
+  GRAPH  <http://mu.semte.ch/graphs/organisatieportaal> {
+    <http://data.lblod.info/id/information-request-reason/3aeec145-acf3-4b6e-9c00-5b8e285736e0> a ext:ReasonCode,
+        skos:Concept;
+        mu:uuid "3aeec145-acf3-4b6e-9c00-5b8e285736e0";
+        skos:prefLabel "Aanmaken van een persoon".
+
+    <http://data.lblod.info/id/information-request-reason/3beec145-acf3-4b6e-9c00-5b8e285736e1> a ext:ReasonCode,
+        skos:Concept;
+        mu:uuid "3beec145-acf3-4b6e-9c00-5b8e285736e1";
+        skos:prefLabel "In het kader van administratief toezicht".
+
+    <http://data.lblod.info/id/information-request-reason/3beec145-acf3-4b6e-9c00-5b8e285736e2> a ext:ReasonCode,
+        skos:Concept;
+        mu:uuid "3beec145-acf3-4b6e-9c00-5b8e285736e2";
+        skos:prefLabel "In het kader van een screeningsdossier".
+
+    <http://data.lblod.info/id/information-request-reason/3beec145-acf3-4b6e-9c00-5b8e285736e3> a ext:ReasonCode,
+        skos:Concept;
+        mu:uuid "3beec145-acf3-4b6e-9c00-5b8e285736e3";
+        skos:prefLabel "In het kader van een erkenningsdossier".
+
+    <http://data.lblod.info/id/information-request-reason/3beec145-acf3-4b6e-9c00-5b8e285736e4> a ext:ReasonCode,
+        skos:Concept;
+        mu:uuid "3beec145-acf3-4b6e-9c00-5b8e285736e4";
+        skos:prefLabel "In het kader van een wijzigingsdossier".
+
+    <http://data.lblod.info/id/information-request-reason/3beec145-acf3-4b6e-9c00-5b8e285736e5> a ext:ReasonCode,
+        skos:Concept;
+        mu:uuid "3beec145-acf3-4b6e-9c00-5b8e285736e5";
+        skos:prefLabel "In het kader van een informatie-uitwisseling (cfr. protocol) met een overheidsinstelling".
+  }
+}
--- a/config/resources/change-events.json
+++ b/config/resources/change-events.json
@@ -58,7 +58,7 @@
      "attributes": {},
      "relationships": {
        "resulting-organization": {
-          "predicate": "org:organization",
+          "predicate": "ext:resultingOrganization",
          "target": "organizations",
          "cardinality": "one"
        },
--- a/config/resources/domain.json
+++ b/config/resources/domain.json
@@ -210,6 +210,10 @@
        "website": {
          "type": "uri",
          "predicate": "foaf:page"
+        },
+        "type": {
+          "type": "string",
+          "predicate": "schema:contactType"
        }
      }, 
      "relationships": {
@@ -311,7 +315,7 @@
          "inverse": true
        },
        "change-event-results": {
-          "predicate": "org:organization",
+          "predicate": "ext:resultingOrganization",
          "target": "change-event-results",
          "cardinality": "many",
          "inverse": true
--- a/docker-compose.yml
+++ b/docker-compose.yml
@@ -158,7 +158,7 @@ services:
    restart: always
    logging: *default-logging
  frontend:
-    image: lblod/frontend-contact-hub:1.5.0
+    image: lblod/frontend-contact-hub:1.6.0
    volumes:
      - ./config/frontend/add-x-frame-options-header.conf:/config/add-x-frame-options.conf
    environment:
Author	SHA1	Message	Date
Claire Lovisa	ab12f4e15b	Add migration to remove duplicated organizations	2022-03-08 17:58:04 +01:00
Claire Lovisa	d0473d35a2	Add migration to update change event and status	2022-03-08 17:57:56 +01:00
Claire Lovisa	09fbb2d06a	Add migration to fix change event date	2022-03-08 17:57:50 +01:00
Claire Lovisa	3b6a5f8c44	Add migration to delete CKB Wachtebeke	2022-03-08 17:57:42 +01:00
Nordine Bittich	88226a9038	bump frontend	2022-02-10 16:02:13 +01:00
Sam Van Campenhout	f8a5935004	Add a type attribute to the contact-points model (#95 )	2022-02-10 14:23:10 +01:00
Nordine Bittich	cdf4417ca5	bump frontend	2022-02-10 14:09:45 +01:00
Boris De Vloed	5a318a99fe	add contact types (#88 ) * add contact types * move migration to 2022 directory Co-authored-by: Nordine Bittich <nordine@bittich.be>	2022-02-10 13:53:48 +01:00
Nordine Bittich	f36e2ba706	bump frontend	2022-02-01 18:05:20 +01:00
Nordine Bittich	f41430b699	bump frontend	2022-01-26 15:43:11 +01:00
Sam Van Campenhout	422e92a343	Temporarily rename the change-event-result organization relationship (#94 ) This relationship uses the same `org:organization` predicate that is also used for the local involvements relationship. When querying for local involvements data when an organization also has change events data, mu-cl-resources receives the change events data instead and runs into errors. This is likely a bug in the micro service itself. Renaming the predicate is a quick workaround so we have more time to find the real solution for the problem without a broken app.	2022-01-25 20:04:18 +01:00
Nordine Bittich	b5a7eb1755	bump frontend	2022-01-24 11:28:47 +01:00
claire-lovisa	a3478e997c	Merge pull request #93 from lblod/features/new-reasons-code add new reason code	2022-01-20 14:53:33 +01:00
Nordine Bittich	7aa969c17b	add new reason code	2022-01-20 10:27:55 +01:00